[原创]教育部CAE考试ANSYS分析样题-直角拐变形和应力计算

2017-02-24  by:CAE仿真在线  来源:互联网

导读:掌握空间梁结构的建模过程,熟练进行后处理(反力列表、内力图、应力云图和变形云图),约束反力和变形是在整体坐标系下输出的,内力和应力是在梁单元的单元坐标系下输出的。

---

一、问题描述

直角拐的AB 杆与 AC 轴刚性连接,A为轴承,允许 AC 轴的A 端截面在轴承内转动,但不能移动。已知 P =60 N,E=210 GPa,μ =0.25,图中长度单位:mm。计算B点的垂直位移和扭转角,AB杆弯曲产生的正应力,AC杆扭转产生的切应力。样题来源:网络。

问题分析:AB杆产生弯曲变形,AC杆产生扭转变形,用梁单元BEAM188建模分析。梁单元的单元属性有单元类型、截面属性和材料属性。ANSYS无单位,需自己统一,本次采用N、mm和MPa单位制,力矩是N.mm。A、B和C点的坐标分别取关键点1(500,0,0),关键点2(500,0,-300),关键点3(0,0,0)。A和B连线为线1,A和C连线为线2。单元尺寸取10mm。

计算结果汇总

B点铅垂位移:-8.227 mm

B点扭转角:-0.038 rad

AB杆弯曲正应力:216 MPa

AC杆扭转切应力:11.5 MPa

(1)挠度云图,B点铅垂位移-8.227mm。

(2)转角云图,B点扭转角-0.038rad。

(3)弯曲正应力云图,最大数值在AB杆的B点上下两侧,216MPa。

(4)扭转切应力云图,最大数值在AC杆的整个圆周表面,11.5MPa。

二、GUI步骤

1.进入ANSYS

程序→ ANSYS → ANSYS Product Launcher → 改变working directory到指定文件夹→ 在job name输入:file → Run。

2.定义单元属性

(1)定义单元类型:

①指定BEAM188单元:MainMenu >Preprocessor >Element Type >Add/Edit/Delete →Add →在左列表框中选择Beam,在右列表框中选择2 node 188 →OK。

②设置单元选项:Options →Elementbehavior K3:Cubic Form(三次形函数) →OK。默认情况下Element behavior是一次形函数,为了提高计算精度和减少单元个数,改成三次形函数。低版本只有一次和二次形函数,高版本增加了三次形函数。

(2)定义截面:

①AB截面:MainMenu >Preprocessor >Sections >Beam >Common Sections →ID:1;Sub-Type:矩形截面;B:10;H:5;Nb:0;Nh:0→Meshview →OK。ID为截面编号。

默认情况下高度为H,宽度为B,高度沿坐标系的Z方向。想要本例高度沿Y方向,将B和H的数值交换一下即可。

②AC截面:MainMenu >Preprocessor >Sections >Beam >Common Sections →ID:2;Sub-Type:圆形截面;R:10;N:0;T:0→Meshview →OK。

(3)设置材料属性:MainMenu > Preprocessor > Material Props > Material Models → Structural→ Linear → Elastic → Isotropic → EX:2.1E5;PRXY:0.25→ OK。

3.建立几何模型

(1)调整视图:选择窗口右侧的按钮。

(2)生成关键点:Main Menu >Preprocessor >Modeling >Create >Keypoints >In Active CS →依次输入关键点的编号和坐标:1 (500,0,0),2 (500,0,-300),3 (0,0,0) →OK。

(3)创建直线:MainMenu >Preprocessor >Modeling >Create >Lines >Lines >Straight Line →依次拾取1和2,1和3 →OK。

(4)打开关键点和线编号:Utility Menu > PlotCtrls > Numbering→KP Keypoint numbers:ON,LINE Line numbers:ON→ OK。

4.划分网格

(1)设置线的单元属性:

①设置AB杆的截面属性:MainMenu >Preprocessor >Meshing >Mesh Tool →在Element Attributes下方选择Lines Set→ 拾取线L1→OK →选择MAT:1,TYPE:1,SECT:1→OK。

②设置AC杆的截面属性:MainMenu >Preprocessor >Meshing >Mesh Tool →在ElementAttributes下方选择LinesSet→ 拾取线L2→OK →选择MAT:1,TYPE:1,SECT:2→OK。

(2)设置单元尺寸:MainMenu >Preprocessor >Meshing >Mesh Tool →在Size Controls下方选择Global Set →SIZE:10→OK。每10mm划分一个单元。

(3)划分梁单元:MainMenu >Preprocessor >Meshing >Mesh Tool →Mesh:Lines→ Mesh → Pick All。

(4)打开梁单元的单元形状:Utility Menu >PlotCtrls>Style >Size and Shape →[/ESHAPE]: On。

(5)显示单元:Utility Menu > Plot > Element。

5.施加边界条件

(1)施加约束:MainMenu>Solution>Define Loads>Apply>Structural>Displacement>OnKeypoints →拾取关键点K1→OK → Lab2:UY和UZ→ Apply →拾取关键点K3→ OK → Lab2:ALL→ OK。

(2)施加载荷:MainMenu >Solution >Define Loads >Apply >Structural >Force/Moment >OnKeypoints → 拾取关键点K2→ OK → Lab:FY,VALUE:-60 →OK。

(3)求解前保存模型:UtilityMenu > Files > Save as → 输入file1.db→ OK。

6.求解

(1)求解:MainMenu > Solution > Solve > Current LS → File > Close → Solve CurrentLoad Step → OK → Solution is done → Close。

(2)保存结果文件:UtilityMenu > Files > Save as → 输入file2.db→ OK。

7.后处理

(1)弯曲变形(挠度和转角)

①挠度云图:UtilityMenu >Plot >Results >Contour Plot >Nodal Solution → Y - Component of displacement→OK。出图并记录数据。

②转角云图:UtilityMenu >Plot >Results >Contour Plot >Nodal Solution → X - Component of rotation→OK。出图并记录数据。

(2)应力云图(切应力和正应力)

①扭转切应力云图:MainMenu >General Postproc >Plot Results >Contour Plot >Nodal Solu → XY Shear stress → OK。出图并记录数据。

②正应力云图:MainMenu >General Postproc >Plot Results >Contour Plot >Nodal Solu →X-Component stress → OK。出图并记录数据。

(3)列表查看约束反力:

①MainMenu > General Postproc > List Results > Reaction Solu → All strucforc F → OK。

②MainMenu > General Postproc > List Results > Reaction Solu → All struc mome M → OK。

记录数据,体会反力为什么是这个方向。节点1是A点的反力,节点12是C点反力。

(4)查找定义内力(剪力、弯矩和扭矩)单元表的方法

①打开梁单元的单元坐标系:UtilityMenu >PlotCtrls >Symbols →ESYS:On→OK。

②检查梁单元的单元坐标系,看不清请把单元形状关掉,检查后再把单元形状打开。单元坐标系的X、Y和Z坐标的颜色与整体坐标系相同。内力输出是在梁单元的单元坐标系下输出的。可以判断出,AB段的剪力是FY,AB段的弯矩是MZ,AC段的扭矩是MX。

③打开梁单元的单元坐标系:UtilityMenu>PlotCtrls>Symbols →ESYS:Off→OK。

④查找定义BEAM188内力单元表的方法:打开ANSYS Help,搜索BEAM188。

A.找到BEAM188的单元介绍页面后,页面中查表Table188.1: BEAM188 Element Output Definitions。

表中查找Name:SF:y,z,Definition:Section shear forces,在Name栏中SFy便是剪力。

表中查找Name:My,Mz,Definition:Bending moments,在Name栏中MZ便是弯矩。

表中查找Name:TQ,Definition:Torsional moment,在Name栏中TQ便是扭矩。

B.页面中查表Table188.2: BEAM188 Item and Sequence Numbers。表中查找Output Quantity Name,Item,I,J对应的代号。

Table188.2: BEAM188 Item and Sequence Numbers

Output Quantity Name	ETABLE and ESOL Command Input
	Item	E	I	J
Fx-轴力	SMISC	--	1	14
My-弯矩	SMISC	--	2	15
Mz-弯矩	SMISC	--	3	16
TQ-扭矩	SMISC	--	4	17
SFz-剪力	SMISC	--	5	18
SFy-剪力	SMISC	--	6	19

(3)剪力图

①定义剪力单元表:MainMenu > General Postproc > Element Table > Define Table → Lab:输入SFY_I→ Item:选择Bysequence num → Comb:选择SMISC,在SMISC后面输入“6” →OK → Apply → Lab:输入SFY_J→ Item:选择By sequence num → Comb:选择SMISC,在SMISC后面输入“19”→ OK → Close。

②剪力云图:MainMenu > General Postproc > Plot Results > Contour Plot > Line ElemRes → LabI选择SFY_I,LabJ选择SFY_J→ OK。

③剪力列表:MainMenu > General Postproc > Element Table > List Element Table → 选择SFY_I和SFY_J→ OK → 记录弯矩值→ File → Close。

(4)弯矩图

①定义弯矩单元表:MainMenu > General Postproc > Element Table > Define Table → Lab:输入MZ_I→ Item:选择Bysequence num → Comb:选择SMISC,在SMISC后面输入“3” →OK → Apply → Lab:输入MZ_J→ Item:选择Bysequence num → Comb:选择SMISC,在SMISC后面输入“16”→ OK → Close。

②弯矩云图:MainMenu > General Postproc > Plot Results > Contour Plot > Line ElemRes → LabI选择MZ_I,LabJ选择MZ_J→ OK。

③将弯矩单位N.mm转换成N.m:Main Menu >General Postproc >Element Table>Add Items → LabR:MZ_I,FACT1:1e-3,Lab1:MZ_I → Apply → LabR:MZ_J,FACT1:1e-3,Lab1:MZ_J → OK。

④重新画弯矩云图:MainMenu > General Postproc > Plot Results > Contour Plot > Line ElemRes → LabI选择MZ_I,LabJ选择MZ_J→ OK。单位N.m。

⑤弯矩列表:MainMenu > General Postproc > Element Table > List Element Table → 选择MZ_I和MZ_J→ OK → 记录弯矩值→ File → Close。

(4)扭矩图

①定义扭矩单元表:MainMenu > General Postproc > Element Table > Define Table → Lab:输入TQ_I→ Item:选择Bysequence num → Comb:选择SMISC,在SMISC后面输入“4” → OK→ Apply → Lab:输入TQ_J→ Item:选择Bysequence num → Comb:选择SMISC,在SMISC后面输入“17” →OK → Close。

②扭矩云图:MainMenu > General Postproc > Plot Results > Contour Plot > Line ElemRes → LabI选择TQ_I,LabJ选择TQ_J→ OK。

③将扭矩单位N.mm转换成N.m:Main Menu >General Postproc >Element Table>Add Items → LabR:TQ_I,FACT1:1e-3,Lab1:TQ_I → Apply → LabR:TQ_J,FACT1:1e-3,Lab1:TQ_J → OK。

④重新画扭矩云图:MainMenu > General Postproc > Plot Results > Contour Plot > Line ElemRes → LabI选择TQ_I,LabJ选择TQ_J→ OK。单位N.m。

⑤扭矩列表:MainMenu > General Postproc > Element Table > List Element Table → 选择TQ_I和TQ_J→ OK → 记录扭矩值→ File → Close。

8.退出ANSYS软件

Utility Menu> File > Exit → Quit-No Save → OK。

五、APDL步骤

FINISH

/CLEAR,NOSTART

/PREP7

ET,1,BEAM188 !单元类型

KEYOPT,1,3,2 !形函数

KEYOPT,1,4,2 !包含扭转和弯曲的切应力

MP,EX,1,2.1e5 !材料属性MPa

MP,PRXY,1,0.25

SECTYPE, 1, BEAM, RECT, ,0 !AB截面属性mm

SECOFFSET, CENT

SECDATA,10,5,0,0,0,0,0,0,0,0,0,0

SECTYPE, 2, BEAM, CSOLID, ,0 !AC截面属性mm

SECOFFSET, CENT

SECDATA,10,0,0,0,0,0,0,0,0,0,0,0

/VIEW,1,1,1,1 !视图

K,1,500,0,0, !创建关键点mm

K,2,500,0,-300,

K,3,0,0,0,

L,1,2 !创建线

L,1,3

/PNUM,KP,1 !关键点编号

/PNUM,LINE,1 !线编号

LSEL,S , , , 1

LATT,1, ,1, , , ,1

LSEL,S, , , 2

LATT,1, ,1, , , ,2

ALLSEL,ALL

LESIZE,ALL, , ,10, , , , ,1 !单元尺寸mm

LMESH,ALL !线分网

/ESHAPE,1.0 !单元形状

DK,1,UY !A点约束

DK,1,UZ

DK,3,ALL !C点约束

FK,2,FY,-60 !B点集中力

FINISH

/SOLU

SOLVE !求解

FINISH

/POST1

/UDOC,1,DATE,1 !关闭ANSYS标志和时间

/dev,font,1,Courier*New,400,0,-21,0,0,,, !3号字体

/GFORMAT,F,12,3, !数据格式

PLNSOL, U,Y, 0,1.0 !挠度

PLNSOL, ROT,X, 0,1.0 !弯曲角rad

/GFORMAT,F,12,1, !数据格式

PLNSOL, S,X, 0,1.0 !弯曲正应力

PLNSOL, S,XY, 0,1.0 !扭转切应力

PRRSOL,F !约束反力列表

ETABLE,SFY_I,SMISC, 6 !定义剪力单元表

ETABLE,SFY_J,SMISC, 19

/VIEW,1,1 !视图

PLLS,SFY_I,SFY_J,1,0 !剪力图云图

PRETAB,SFY_I,SFY_J !剪力列表

ETABLE,MZ_I,SMISC, 3 !定义弯矩单元表

ETABLE,MZ_J,SMISC, 16

PLLS,MZ_I,MZ_J,1,0 !弯矩图云图N.mm

SADD,MZ_I,MZ_I, ,1E-3,1, , !将弯矩单位N.mm转换成N.m

SADD,MZ_J,MZ_J, ,1E-3,1, ,

PRETAB,MZ_I,MZ_J !弯矩列表N.m

PLLS,MZ_I,MZ_J,1,0 !弯矩图云图N.m

ETABLE,TQ_I,SMISC, 4 !定义扭矩单元表

ETABLE,TQ_J,SMISC, 17

/VIEW,1,,,1 !视图

PLLS,TQ_I,TQ_J,1,0 !扭矩图云图N.mm

SADD,TQ_I,TQ_I, ,1E-3,1, , !将扭矩单位N.mm转换成N.m

SADD,TQ_J,TQ_J, ,1E-3,1, ,

PRETAB,TQ_I,TQ_J !扭矩列表N.m

PLLS,TQ_I,TQ_J,1,0 !扭矩图云图N.m

相关标签搜索：[原创]教育部CAE考试ANSYS分析样题-直角拐变形和应力计算 Ansys有限元培训 Ansys workbench培训 ansys视频教程 ansys workbench教程 ansys APDL经典教程 ansys资料下载 ansys技术咨询 ansys基础知识 ansys代做 Fluent、CFX流体分析 HFSS电磁分析 Abaqus培训